Installing Samsung Kies in multiple languages

image_pdfimage_print

Samsung Kies is used to administer a Samsung Galaxy mobile device. You can backup data, restore data, update your device etc. The company I am working for has the policy that mail may not be read on the mobile device. Thus the users should get a notification when starting Samsung Kies.

Samsung Kies has the following pre requirements:

  • .Net Framework 4.0 Full
  • NDP40-KB2461678

So I did the following:

  • Installed the application
  • Started Samsung Kies, selected all the languages and downloaded the language files:

    Folder structure for the language files used by Samsung Kies.

    Folder structure for the language files used by Samsung Kies.

The code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
' ================================================================================================
' Installs Samsung Kies.
' Created by Willem-Jan Vroom
' Version history:
'
' 0.0.1
'    Initial version
'
' 0.0.2
'    Improved x64 support
'    Only a uninstall is possible.
'
' 0.0.3:
'    Registers kies.exe with Dot Net Framework 4.0.30319.
' ================================================================================================
 
' ------------------------------------------------------------------------------------------------
' Declare the most variables.
' ------------------------------------------------------------------------------------------------
 
  Option Explicit
 
  Dim objShell                          : set objShell                      = WScript.CreateObject("WScript.Shell")
  Dim objLogFileFSO                     : Set objLogFileFSO                 = CreateObject("Scripting.FileSystemObject")
  Dim objFSO                            : Set objFSO                        = CreateObject("Scripting.FileSystemObject")
  Dim objProcessEnv                     : Set objProcessEnv                 = objShell.Environment("PROCESS")
  Dim objWMIService                     : Set objWMIService                 = GetObject("winmgmts:\\.\root\cimv2")
  Dim fn_objWMIService                  : Set fn_objWMIService              = GetObject("winmgmts:\\.\root\cimv2")
  Dim objReg                            : Set objReg                        = GetObject("winmgmts:\\.\root\default:StdRegProv")
  Dim objLogFile
  Dim CurrentDir                        : CurrentDir                        = Left(Wscript.ScriptFullname, InstrRev(Wscript.ScriptFullname, "\"))
                                          CurrentDir                        = Left(CurrentDir,len(CurrentDir)-1)
  Dim strcomputerName                   : strcomputerName                   = objProcessEnv("COMPUTERNAME")
  Dim strLogLocation                    : strLogLocation                    = "C:\WINDOWS\system32\Logfiles"
  Dim strOutputFile                     : strOutputFile                     = strLogLocation & "\" & strcomputerName & "_Installation_Samsung_Kies_" & Replace(FormatDateTime(Now(), 2),"/","-") & ".log"
  Dim strArchitecture                   : strArchitecture                   = "x86"
  Dim strCurrentUser                    : strCurrentUser                    = ""
  Dim strCurrentUserSID                 : strCurrentUserSID                 = ""
  Dim strOS                             : strOS                             = ""
  Dim strCommand                        : strCommand                        = ""
  Dim strLine                           : strLine                           = ""
  Dim strQuery                          : strQuery                          = ""
  Dim strCommonDesktop                  : strCommonDesktop                  = ""
  Dim strArray                          : strArray                          = ""
  Dim strAppDataFolder                  : strAppDataFolder                  = ""
  Dim strProcess                        : strProcess                        = ""
  Dim strLanguage                       : strLanguage                       = ""
  Dim strInstallLanguage                : strInstallLanguage                = ""
  Dim strDetectUserUILanguage           : strDetectUserUILanguage           = ""
  Dim strValue                          : strValue                          = ""
  Dim strKeyPath                        : strKeyPath                        = ""
  Dim strValueName                      : strValueName                      = ""
  Dim strCommonPrograms                 : strCommonPrograms                 = ""
  Dim strFileToDelete                   : strFileToDelete                   = ""
  dim strProgramFilesFolder             : strProgramFilesFolder             = objProcessEnv("ProgramFiles")
  Dim strDotNetInstallPath              : strDotNetInstallPath              = ""
  Dim strWindir                         : strWinDir                         = objShell.ExpandEnvironmentStrings("%WinDir%")
  Dim dwValue                           : dwValue                           = 0
 
  Dim arrFileNamesToKill                : arrFileNamesToKill                = Array("KiesAgent.exe", "KiesTrayAgent.exe","kies.exe","kiespdlr.exe")
  Dim objFileNameToKill
 
  Dim arrArguments
  Dim arrLanguage
  Dim strDNSDomain                      : strDNSDomain                      = CreateObject("ADSystemInfo").DomainShortName
  Dim valCounter
  Dim valResult
  Dim valReturnCode
 
  Dim colProcess, objProcess
  Dim valOSBuildNumber
  Dim objSubfolder
  Dim colItems, objItem, Subfolder
  Dim colSoftware, objSoftware
  Dim arrValues, arrSubKeys
 
  Const ForWriting           = 2
  Const ForReading           = 1
  Const ForAppending         = 8
  Const OverWriteFiles       = True
  const HKEY_CURRENT_USER    = &H80000001
  const HKEY_LOCAL_MACHINE   = &H80000002
  Const HKEY_USERS           = &H80000003
 
  Const DEBUGMODE            = False
 
' ------------------------------------------------------------------------------------------------
' Create the log location (if not exists)
' Open the logfile.
' ------------------------------------------------------------------------------------------------
 
  CreateFolderStructure(strLogLocation)
  OpenLogFile()
  WriteToLog "- ACTION: script started."
  WriteToLog " "
 
' ------------------------------------------------------------------------------------------------
' Detect the current OS.
' ------------------------------------------------------------------------------------------------
 
  Set colItems = objWMIService.ExecQuery("Select Caption,BuildNumber from Win32_OperatingSystem")
  For Each objItem in colItems
      strOS            = objItem.Caption
      valOSBuildNumber = objItem.BuildNumber
  next
 
' ------------------------------------------------------------------------------------------------
' Find the currently logged on userid.
' And translate it to the users SID.
' ------------------------------------------------------------------------------------------------
 
  Set colProcess = objWMIService.ExecQuery("Select * from Win32_Process where Name = 'explorer.exe'")
  For Each objProcess in colProcess
      valReturnCode = objProcess.GetOwner(strCurrentUser)
      if valReturnCode <> 0 Then strCurrentUser = "Unable to find the username!"
  Next
 
  strCurrentUser = Ucase(strDNSDomain) & "\" & strCurrentUser
 
  strCurrentUserSID = GetSIDFromUser(strCurrentUser)
 
' ------------------------------------------------------------------------------------------------
' Detect the current processor architecture.
' ------------------------------------------------------------------------------------------------
 
  if objFSO.FolderExists(strWindir & "\syswow64") Then
     strArchitecture = "x64"
     strProgramFilesFolder = objProcessEnv("ProgramFiles(x86)")
  end if
 
' ------------------------------------------------------------------------------------------------
' Detect the current User Interface MUI.
' ------------------------------------------------------------------------------------------------
 
  strDetectUserUILanguage = DetectUserUILanguage
 
  WriteToLog("########## Details regarding operating system and logged on user     ##########")
  WriteToLog("Found Operating System:       " & strOS)
  WriteToLog("Found architecture:           " & strArchitecture)
  WriteToLog("Logged on userid:             " & strCurrentUser)
  WriteToLog("Logged on user SID:           " & strCurrentUserSID)
  WriteToLog("Language:                     " & strDetectUserUILanguage)
  WriteToLog("########## End details regarding operating system and logged on user ##########")
  WriteToLog(" ")
  WriteToLog("########## Installation                                              ##########")
 
  ' ------------------------------------------------------------------------------------------------
  ' Close applications that might screw up the installation.
  ' ------------------------------------------------------------------------------------------------
 
  For Each objFileNameToKill in arrFileNamesToKill
    fnKillProcess(objFileNameToKill)
  Next
 
' ------------------------------------------------------------------------------------------------
' Sets SEE_MASK_NOZONECHECKS to 1.
' That will avoid a screen that asks for permission to run an application from
' a share or mapped drive.
' ------------------------------------------------------------------------------------------------
 
  objProcessEnv("SEE_MASK_NOZONECHECKS") = 1
 
' ------------------------------------------------------------------------------------------------
' Uninstall other Samsung Kies installations.
' if the command line option '/uninstall' is given, then only a uninstall and quit.
' ------------------------------------------------------------------------------------------------
 
  if wscript.arguments.count > 0 Then
     if lcase(wscript.arguments(0)) = "/uninstall" then
	    WriteToLog("The command line option '" & wscript.arguments(0) & "' was found, so only a silent uninstall will be performed.")
        RemoveSamsungKies()
        WriteToLog("########## End Uninstall of Samsung Kies                             ##########")
        WriteToLog(" ")
        CloseLogFile()
        wscript.quit
     end if
  end if
 
' ------------------------------------------------------------------------------------------------
' Install prereq 1: .Net 4 Full
' Only if not already installed.
' ------------------------------------------------------------------------------------------------
 
  WriteToLog(" ")
  WriteToLog("---------- Install .Net Framework 4.0 Full                           ----------")
  WriteToLog(" ")
 
  strKeyPath = "SOFTWARE\Microsoft\Net Framework Setup\NDP\v4\Full"
 
  objReg.EnumKey HKEY_LOCAL_MACHINE, strKeyPath, arrSubKeys
  if isNull(arrSubKeys) then
     strCommand = chr(34) & CurrentDir & "\Externals\Net 4.0\dotNetFx40_Full_x86_x64.exe" & chr(34)
     strCommand = strCommand & " /norestart /q /x86 /x64"
     WriteToLog("Running command: " & strCommand)
     valResult = objShell.Run (strCommand, 6 ,True)
     WriteToLog("Result: " & valResult)
       else
     WriteToLog(".Net 4.0 Full has already been installed, thus skipping.")
  end if
 
' ------------------------------------------------------------------------------------------------
' Install prereq 2: NDP40-KB2461678
' Only on x86
' ------------------------------------------------------------------------------------------------
 
  if strArchitecture = "x86" then
  WriteToLog(" ")
  WriteToLog("---------- NDP40-KB2461678                                           ----------")
  WriteToLog(" ")
 
     strCommand = chr(34) & CurrentDir & "\Externals\Net 4.0\NDP40-KB2461678-x86.exe" & chr(34)
     strCommand = strCommand & " /norestart /q"
     WriteToLog("Running command: " & strCommand)
     valResult = objShell.Run (strCommand, 6 ,True)
     WriteToLog("Result: " & valResult)
  end if
 
' ------------------------------------------------------------------------------------------------
' Start the base installation
' ------------------------------------------------------------------------------------------------
 
  WriteToLog(" ")
  WriteToLog("---------- Install the base application Samsung Kies                 ----------")
  WriteToLog(" ")
 
  strCommand = chr(34) & CurrentDir & "\Kiessetup.exe" & chr(34)
  strCommand = strCommand & " /s /v" & chr(34) & "ISALWAYSINSTALLELEVATED=1 /qn /l*v c:\windows\system32\logfiles\Samsung_Kies_2.5.1.12123_MLI_XP_P1.log" & chr(34)
  WriteToLog ("Running command: " & strCommand)
  valResult = objShell.Run (strCommand,6,True)
  WriteToLog("Result: " & valResult)
' RegisterKiesExecutableWithDotNet40()
  CopyLangFiles()
  ModifyIcons()
  WriteToLog("########## End Installation                                          ##########")
  WriteToLog(" ")
  CloseLogFile()
  wscript.quit valReturnCode
 
Sub CopyLangFiles()
 
' ------------------------------------------------------------------------------------------------
' Subroutine: CopyLangFiles()
' Copies the language files
' ------------------------------------------------------------------------------------------------
 
 objFSO.CopyFolder CurrentDir & "\Locale" , strProgramFilesFolder & "\Samsung\Kies\Locale" , OverWriteFiles
 
End Sub
 
Sub ModifyIcons()
 
' ------------------------------------------------------------------------------------------------
' Subroutine: ModifyIcons()
' Removes all the Kies icons from both the Desktop and Start Menu and replace it by a modified
' version
' ------------------------------------------------------------------------------------------------
 
  WriteToLog(" ")
  WriteToLog("---------- Modify the icons on both the desktop and Start Menu.      ----------")
  WriteToLog(" ")
 
  objFSO.CopyFile CurrentDir & "\shortcut.vbs",strProgramFilesFolder & "\samsung\kies\"
 
  strKeyPath       = "SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders"
  strValueName     = "Common Desktop"
  objReg.GetStringValue HKEY_LOCAL_MACHINE,strKeyPath,strValueName,strCommonDesktop
 
  strFileToDelete  = strCommonDesktop & "\Samsung Kies.lnk"
  if objFSO.FileExists(strFileToDelete) then objFSO.DeleteFile strFileToDelete
 
  strFileToDelete  = strCommonDesktop & "\Samsung Kies (Lite).lnk"
  if objFSO.FileExists(strFileToDelete) then objFSO.DeleteFile strFileToDelete
 
  strKeyPath       = "SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders"
  strValueName     = "Common Programs"
  objReg.GetStringValue HKEY_LOCAL_MACHINE,strKeyPath,strValueName,strCommonPrograms
 
  strFileToDelete  = strCommonPrograms & "\Samsung\Kies\Samsung Kies.lnk"
  if objFSO.FileExists(strFileToDelete) then objFSO.DeleteFile strFileToDelete
 
  strFileToDelete  = strCommonPrograms & "\Samsung\Kies\Samsung Kies (Lite).lnk"
  if objFSO.FileExists(strFileToDelete) then objFSO.DeleteFile strFileToDelete
 
  strFileToDelete  = strCommonPrograms & "\Samsung\Kies\Uninstall Kies.lnk"
  if objFSO.FileExists(strFileToDelete) then objFSO.DeleteFile strFileToDelete
 
  Dim objShellLink
  set objShellLink              = objShell.CreateShortcut(strCommonPrograms & "\Samsung\Kies\Samsung Kies (Lite).lnk")
  objShellLink.TargetPath       = chr(34) & strProgramFilesFolder & "\Samsung\Kies\shortcut.vbs" & chr(34)
  objShellLink.IconLocation     = strProgramFilesFolder & "\Samsung\Kies\KiesLite.ico, 0"
  objShellLink.WorkingDirectory = strProgramFilesFolder & "\Samsung\Kies\"
  objShellLink.Save
 
  if DEBUGMODE Then
     set objShellLink              = objShell.CreateShortcut(strCommonPrograms & "\Samsung\Kies\Samsung Kies (No VB).lnk")
     objShellLink.TargetPath       = chr(34) & strProgramFilesFolder & "\Samsung\Kies\kies.exe" & chr(34)
     objShellLink.Arguments        = "/lite"
     objShellLink.IconLocation     = strProgramFilesFolder & "\Samsung\Kies\KiesLite.ico, 0"
     objShellLink.WorkingDirectory = strProgramFilesFolder & "\Samsung\Kies"
     objShellLink.Save
  End if
End Sub
 
Sub OpenLogFile()
 
' ------------------------------------------------------------------------------------------------
' Subroutine: OpenLogFile()
' The name of the logfile is mentinoed in the variabele strOutputFile.
' ------------------------------------------------------------------------------------------------
 
  If objLogFileFSO.FileExists(strOutputFile) Then
     Set objLogFile = objLogFileFSO.OpenTextFile(strOutputFile, ForAppending)
         Else
     Set objLogFile = objLogFileFSO.CreateTextFile(strOutputFile)
  End If
 
End Sub
 
Sub CloseLogFile()
 
' ------------------------------------------------------------------------------------------------
' Subroutine: CloseLogFile()
' Close the log file.
' ------------------------------------------------------------------------------------------------
 
  WriteToLog "- ACTION: script ended."
  objLogFile.Close
  Set objLogfileFSO = Nothing
 
End Sub
 
Function WriteToLog(sLogMessage)
 
' ------------------------------------------------------------------------------------------------
' Function: WriteToLog(sLogMessage)
' Writes an entry 'sLogMessage' in the logfile.
' ------------------------------------------------------------------------------------------------
 
  if instr(sLogMessage, "- ACTION: ") = 0 then sLogMessage = "          " & sLogMessage
  objLogFile.WriteLine("Time: " & now & "  " & sLogMessage)
 
End Function
 
Function GetSIDFromUser(UserName)
 
' ------------------------------------------------------------------------------------------------
' Function: GetSIDFromUser(UserName)
' Gets the SID from the give username.
' We use the registry to avoid an empty result if run under the SYSTEM account.
' ------------------------------------------------------------------------------------------------
 
  Dim DomainName, Result, WMIUser
 
  If InStr(UserName, "\") > 0 Then
    DomainName = Mid(UserName, 1, InStr(UserName, "\") - 1)
    UserName = Mid(UserName, InStr(UserName, "\") + 1)
  Else
    DomainName = CreateObject("WScript.Network").UserDomain
  End If
 
  On Error Resume Next
  Set WMIUser = GetObject("winmgmts:{impersonationlevel=impersonate}!" _
    & "/root/cimv2:Win32_UserAccount.Domain='" & DomainName & "'" _
    & ",Name='" & UserName & "'")
  If Err.Number = 0 Then
    Result = WMIUser.SID
  Else
    Result = ""
  End If
  On Error GoTo 0
 
  GetSIDFromUser = Result
 
End Function
 
Sub CreateFolderStructure(strFolderNameToBeCreated)
 
' ------------------------------------------------------------------------------------------------
' Subroutine: CreateFolderStructure(strFolderNameToBeCreated)
' Creates the map as mentioned in strFolderNameToBeCreated.
' ------------------------------------------------------------------------------------------------
 
  Dim arrFoldersTMP : arrFoldersTMP = split (strFolderNameToBeCreated,"\")
  Dim strFolder  : strFolder  = ""
  Dim objFolderTMP
 
  For Each objFolderTMP in arrFoldersTMP
      strFolder = strFolder & objFolderTMP
      If NOT objFSO.FolderExists(strFolder) Then
             objFSO.CreateFolder(strFolder)
      end If
      strFolder = strFolder & "\"
  Next
 
End Sub
 
Function DetectUserUILanguage
 
' ------------------------------------------------------------------------------------------------
' Function: DetectUserUILanguage
' Detects the User Interface Language
' ------------------------------------------------------------------------------------------------
 
  if instr(lcase(strOS),"windows xp") > 0 then
     strKeyPath               = strCurrentUserSID & "\Control Panel\Desktop"
     strValueName             = "MultiUILanguageId"
     strLanguage              = "eng"
     objReg.GetStringvalue HKEY_USERS,strKeyPath,strValueName,strValue
     if NOT IsEmpty(strValue) Then
        strValue = UCase(right(strValue,4))
        if strValue = "040C" then strLanguage = "fra"
        if strValue = "0410" then strLanguage = "ita"
        if strValue = "0407" then strLanguage = "ger"
        if strValue = "040A" then strLanguage = "spa"
        if strValue = "0C0A" then strLanguage = "spa"
     end if
      else
     strKeyPath               = strCurrentUserSID & "\Control Panel\Desktop"
     strValueName             = "PreferredUILanguages"
     strLanguage              = "eng"
     objReg.GetMultiStringValue HKEY_USERS,strKeyPath,strValueName,arrValues
     if not IsNull(arrValues) Then
        strValue=arrValues(0)
        if NOT IsEmpty(strValue) then
           strValue = lcase(left(strValue,5))
           if strValue = "fr-fr" then strLanguage = "fra"
           if strValue = "it-it" then strLanguage = "ita"
           if strValue = "de-de" then strLanguage = "ger"
           if strValue = "es-es" then strLanguage = "spa"
        end if
     end if
     if strLanguage = "eng" then
        strKeyPath               = ".DEFAULT\Control Panel\Desktop\MuiCached"
        strValueName             = "MachinePreferredUILanguages"
        objReg.GetMultiStringValue HKEY_USERS,strKeyPath,strValueName,arrValues
        if not IsNull(arrValues) Then
           strValue=arrValues(0)
           if NOT IsEmpty(strValue) then
              strValue = lcase(left(strValue,5))
              if strValue = "fr-fr" then strLanguage = "fra"
              if strValue = "it-it" then strLanguage = "ita"
              if strValue = "de-de" then strLanguage = "ger"
              if strValue = "es-es" then strLanguage = "spa"
           end if
        end if
     end if
  end if
 
  DetectUserUILanguage = strLanguage
End Function
 
Function fnKillProcess(strProcessName)
 
' ------------------------------------------------------------------------------------------------
' Function: fnKillProcess(strProcessName)
' Terminates the given processname.
' ------------------------------------------------------------------------------------------------
 
  Set colProcess = fn_objWMIService.ExecQuery ("Select * From Win32_Process")
  For Each objProcess In colProcess
    If Instr(LCase(objProcess.Name),LCase(strProcessName)) > 0 Then
       objShell.Run "TASKKILL /F /T /IM " & objProcess.Name, 0, False
       objProcess.Terminate()
       WriteToLog("Terminating application: " & objProcess.Name)
    End If
  Next
 
End Function
 
Function RemoveSamsungKies()
 
' ------------------------------------------------------------------------------------------------
' Function: RemoveSamsungKies()
' Removes all versions of Samsung Kies.
' ------------------------------------------------------------------------------------------------
 
  Set colSoftware = objWMIService.ExecQuery("Select * from Win32_Product Where Name LIKE '%Samsung Kies%'")
 
  For Each objSoftware in colSoftware
     WriteToLog "- AppName: " & objSoftware.Name & " " & objSoftware.Version
     WriteToLog "- ProdID : " & objSoftware.IdentifyingNumber
 
     strCommand = chr(34) & strProgramFilesFolder & "\InstallShield Installation Information\" & objSoftware.IdentifyingNumber & "\setup.exe" & chr(34) & " /removeonly /silent"
     WriteToLog "Running Command: " & strCommand
     valResult = objShell.Run (strCommand,6,True)
     WriteToLog "Result: " & valResult
 
     strKeyPath       = "SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders"
     strValueName     = "Common Programs"
     objReg.GetStringValue HKEY_LOCAL_MACHINE,strKeyPath,strValueName,strCommonPrograms
 
     strFileToDelete  = strCommonPrograms & "\Samsung\Kies\Samsung Kies (Lite).lnk"
     if objFSO.FileExists(strFileToDelete) then objFSO.DeleteFile strFileToDelete
 
     if objFSO.FolderExists(strCommonPrograms & "\Samsung\Kies") Then
        objFSO.DeleteFolder strCommonPrograms & "\Samsung\Kies"
     end if
 
  Next
 
End Function
 
Function RegisterKiesExecutableWithDotNet40()
 
' ------------------------------------------------------------------------------------------------
' Function: RegisterKiesExecutableWithDotNet40
' Registers the base kies.exe with dot net framework 4.0. Otherwise the application does not work.
' If the application is installed under the local SYSTEM account, then this is not done
' automatically.
' ------------------------------------------------------------------------------------------------
 
  WriteToLog(" ")
  WriteToLog("---------- Register Kies.exe with Dot Net Framework.                 ----------")
  WriteToLog(" ")
 
  strKeyPath      = "SOFTWARE\Microsoft\Net Framework Setup\NDP\v4\Full"
  strValueName    = "InstallPath"
 
  objReg.GetStringValue HKEY_LOCAL_MACHINE,strKeyPath,strValueName,strDotNetInstallPath
 
  strCommand      = chr(34) & strDotNetInstallPath & "ngen.exe" & chr(34) & " install " & chr(34) & strProgramFilesFolder & "\Samsung\Kies\Kies.exe" & chr(34) & " /queue:1"
  WriteToLog "Running Command: " & strCommand
  valResult = objShell.Run (strCommand,6,True)
  WriteToLog "Result: " & valResult
 
End Function

And the code for the shortcut.vbs that shows this message when starting Samsung Kies:

Shortcut used by Samsung Kies.

Shortcut used by Samsung Kies.

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
' ================================================================================================
' Starts Samsung Kies in the user language.
' Created by Willem-Jan Vroom
' Version history:
'
' 0.0.1:
'    Initial version
'
' 0.0.2:
'    Creates the registry keys:
'        HKEY_CURRENT_USER\SOFTWARE\SAMSUNG\Kies2.0
'        HKEY_CURRENT_USER\SOFTWARE\SAMSUNG\Kies2.0\FUS
'
' ================================================================================================
 
' ------------------------------------------------------------------------------------------------
' Declare the most variables.
' ------------------------------------------------------------------------------------------------
 
  Option Explicit
 
  Dim objShell                          : set objShell                      = WScript.CreateObject("WScript.Shell")
  Dim objProcessEnv                     : Set objProcessEnv                 = objShell.Environment("PROCESS")
  Dim objFSO                            : Set objFSO                        = CreateObject("Scripting.FileSystemObject")
  Dim objWMIService                     : Set objWMIService                 = GetObject("winmgmts:\\.\root\cimv2")
  Dim objReg                            : Set objReg                        = GetObject("winmgmts:\\.\root\default:StdRegProv")
 
  Dim strMessage                        : strMessage                        = ""
  Dim strLanguage                       : strLanguage                       = ""
  Dim strArchitecture                   : strArchitecture                   = ""
  Dim strOS                             : strOS                             = ""
  Dim strValue                          : strValue                          = ""
  Dim strKeyPath                        : strKeyPath                        = ""
  Dim strValueName                      : strValueName                      = ""
  Dim strDetectUserUILanguage           : strDetectUserUILanguage           = ""
  Dim strCommand                        : strCommand                        = ""
  Dim strWindir                         : strWinDir                         = objShell.ExpandEnvironmentStrings("%WinDir%")
  Dim CurrentDir                        : CurrentDir                        = Left(Wscript.ScriptFullname, InstrRev(Wscript.ScriptFullname, "\"))
                                          CurrentDir                        = Left(CurrentDir,len(CurrentDir)-1)
  dim strProgramFilesFolder             : strProgramFilesFolder             = objProcessEnv("ProgramFiles")
  Dim dwValue                           : dwValue                           = 0
 
  Dim colProcess, objProcess
  Dim valOSBuildNumber
  Dim objSubfolder, valResult
  Dim colItems, objItem, Subfolder
  Dim colSoftware, objSoftware
  Dim arrValues
 
  Const ForWriting           = 2
  Const ForReading           = 1
  Const ForAppending         = 8
  Const OverWriteFiles       = True
  const HKEY_CURRENT_USER    = &H80000001
  const HKEY_LOCAL_MACHINE   = &H80000002
  Const HKEY_USERS           = &H80000003
 
' ------------------------------------------------------------------------------------------------
' Detect the current OS.
' ------------------------------------------------------------------------------------------------
 
  Set colItems = objWMIService.ExecQuery("Select Caption,BuildNumber from Win32_OperatingSystem")
  For Each objItem in colItems
      strOS            = objItem.Caption
      valOSBuildNumber = objItem.BuildNumber
  next
 
' ------------------------------------------------------------------------------------------------
' Detect the current processor architecture.
' ------------------------------------------------------------------------------------------------
 
  if objFSO.FolderExists(strWindir & "\syswow64") Then
     strArchitecture = "x64"
     strProgramFilesFolder = objProcessEnv("ProgramFiles(x86)")
  end if
 
' ------------------------------------------------------------------------------------------------
' Detect the user Languge.
' ------------------------------------------------------------------------------------------------
 
  strDetectUserUILanguage = DetectUserUILanguage
 
' ------------------------------------------------------------------------------------------------
' Write registry information:
'   HKEY_CURRENT_USER\Software\Samsung\Kies2.0
'      Language        -> fr-FR
'      NotifyUpdate    -> 0
'      UpdateMode      -> A
' ------------------------------------------------------------------------------------------------
 
  if strDetectUserUILanguage = "eng" then strDetectUserUILanguage = "en-GB"
  if strDetectUserUILanguage = "fra" then strDetectUserUILanguage = "fr-FR"
  if strDetectUserUILanguage = "ger" then strDetectUserUILanguage = "de-DE"
  if strDetectUserUILanguage = "esp" then strDetectUserUILanguage = "es-ES"
  if strDetectUserUILanguage = "ita" then strDetectUserUILanguage = "it-IT"
 
  objReg.CreateKey      HKEY_CURRENT_USER, "Software\Samsung\Kies2.0"
  objReg.CreateKey      HKEY_CURRENT_USER, "Software\Samsung\Kies2.0\FUS"
 
  objReg.SetStringValue HKEY_CURRENT_USER, "Software\Samsung\Kies2.0","Language"    ,strDetectUserUILanguage
  objReg.SetDWORDValue  HKEY_CURRENT_USER, "Software\Samsung\Kies2.0","NotifyUpdate","0"
  objReg.SetStringValue HKEY_CURRENT_USER, "Software\Samsung\Kies2.0","UpdateMode"  ,"A"
 
' ------------------------------------------------------------------------------------------------
' Before starting the application inform the user that it is only allowed to synchronise their
' contacts and calender between Outlook and their Samsung Galaxy
' ------------------------------------------------------------------------------------------------
 
  strMessage = "Dear collegue," & vbCRLF & vbcrlf
  strMessage = strMessage & "It is only allowed to synchronise your contacts and calender between" & vbcrlf
  strMessage = strMessage & "Outlook and your Samsung Galaxy mobile phone." & vbcrlf & vbcrlf
  strMessage = strMessage & "Click [Ok] to accept this condition and continue or [Cancel] to quit."
 
  valResult = msgbox(strMessage,257,"Samsung Kies")
 
  if valResult = 1 Then
     if objFSO.FileExists(strProgramFilesFolder & "\Samsung\Kies\kies.exe") Then
        strCommand = chr(34) & strProgramFilesFolder & "\Samsung\Kies\kies.exe" & chr(34) & " /lite"
        objShell.Run strCommand,1,True
		  else
		strMessage = "The file '" & strProgramFilesFolder & "\Samsung\Kies\kies.exe' cannot be found." & vbCrLf
        strMessage = strMessage & "Application is quit."
		valResult = msgbox(strMessage,,"Samsung Kies")
	 end if
  end if
 
Function DetectUserUILanguage
 
' ------------------------------------------------------------------------------------------------
' Function: DetectUserUILanguage
' Detects the User Interface Language
' ------------------------------------------------------------------------------------------------
 
  if instr(lcase(strOS),"windows xp") > 0 then
     strKeyPath               = "Control Panel\Desktop"
     strValueName             = "MultiUILanguageId"
     strLanguage              = "eng"
     objReg.GetStringvalue HKEY_CURRENT_USER,strKeyPath,strValueName,strValue
     if NOT IsEmpty(strValue) Then
        strValue = UCase(right(strValue,4))
        if strValue = "040C" then strLanguage = "fra"
        if strValue = "0410" then strLanguage = "ita"
        if strValue = "0407" then strLanguage = "ger"
        if strValue = "040A" then strLanguage = "spa"
        if strValue = "0C0A" then strLanguage = "spa"
     end if
      else
     strKeyPath               = "Control Panel\Desktop"
     strValueName             = "PreferredUILanguages"
     strLanguage              = "eng"
     objReg.GetMultiStringValue HKEY_CURRENT_USER,strKeyPath,strValueName,arrValues
     if not IsNull(arrValues) Then
        strValue=arrValues(0)
        if NOT IsEmpty(strValue) then
           strValue = lcase(left(strValue,5))
           if strValue = "fr-fr" then strLanguage = "fra"
           if strValue = "it-it" then strLanguage = "ita"
           if strValue = "de-de" then strLanguage = "ger"
           if strValue = "es-es" then strLanguage = "spa"
        end if
     end if
     if strLanguage = "eng" then
        strKeyPath               = ".DEFAULT\Control Panel\Desktop\MuiCached"
        strValueName             = "MachinePreferredUILanguages"
        objReg.GetMultiStringValue HKEY_USERS,strKeyPath,strValueName,arrValues
        if not IsNull(arrValues) Then
           strValue=arrValues(0)
           if NOT IsEmpty(strValue) then
              strValue = lcase(left(strValue,5))
              if strValue = "fr-fr" then strLanguage = "fra"
              if strValue = "it-it" then strLanguage = "ita"
              if strValue = "de-de" then strLanguage = "ger"
              if strValue = "es-es" then strLanguage = "spa"
           end if
        end if
     end if
  end if
 
  DetectUserUILanguage = strLanguage
End Function

Permanent link to this article: https://www.vroom.cc/wordpress/installing-samsung-kies-in-multiple-languages/